1/*  Part of SWI-Prolog
    2
    3    Author:        Jan Wielemaker
    4    E-mail:        J.Wielemaker@vu.nl
    5    WWW:           http://www.swi-prolog.org
    6    Copyright (c)  2003-2014, University of Amsterdam
    7                              VU University Amsterdam
    8    All rights reserved.
    9
   10    Redistribution and use in source and binary forms, with or without
   11    modification, are permitted provided that the following conditions
   12    are met:
   13
   14    1. Redistributions of source code must retain the above copyright
   15       notice, this list of conditions and the following disclaimer.
   16
   17    2. Redistributions in binary form must reproduce the above copyright
   18       notice, this list of conditions and the following disclaimer in
   19       the documentation and/or other materials provided with the
   20       distribution.
   21
   22    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
   23    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
   24    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
   25    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
   26    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
   27    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
   28    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
   29    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
   30    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   31    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
   32    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
   33    POSSIBILITY OF SUCH DAMAGE.
   34*/
   35
   36:- module(make,
   37          [ make/0
   38          ]).   39:- use_module(library(check)).   40:- use_module(library(lists)).   41:- use_module(library(option)).   42:- use_module(library(debug)).   43:- set_prolog_flag(generate_debug_info, false).

   56:- multifile
   57    prolog:make_hook/2.

 make

Reload all source files that have been changed since they were loaded. This predicate peforms the following steps:

1. Compute the set of files that need to be reloaded.
2. Call the hook prolog:make_hook(before, Files)
3. Reload the files
4. Call the hook prolog:make_hook(after, Files)
5. If (4) fails, call list_undefined/0.

The hooks are called with an empty list if no files need reloading.

   74make :-
   75    notrace(make_no_trace).
   76
   77make_no_trace :-
   78    '$update_library_index',
   79    findall(File, modified_file(File), Reload0),
   80    list_to_set(Reload0, Reload),
   81    (   prolog:make_hook(before, Reload)
   82    ->  true
   83    ;   true
   84    ),
   85    print_message(silent, make(reload(Reload))),
   86    maplist(reload_file, Reload),
   87    print_message(silent, make(done(Reload))),
   88    (   prolog:make_hook(after, Reload)
   89    ->  true
   90    ;   list_undefined,
   91        list_void_declarations
   92    ).
   93
   94modified_file(File) :-
   95    source_file_property(Source, modified(Time)),
   96    \+ source_file_property(Source, included_in(_,_)),
   97    Time > 0.0,                     % See source_file/1
   98    (   source_file_property(Source, derived_from(File, LoadTime))
   99    ->  true
  100    ;   File = Source,
  101        LoadTime = Time
  102    ),
  103    (   catch(time_file(File, Modified), _, fail),
  104        Modified > LoadTime
  105    ->  true
  106    ;   source_file_property(Source, includes(Included, IncLoadTime)),
  107        catch(time_file(Included, Modified), _, fail),
  108        Modified > IncLoadTime
  109    ->  true
  110    ).

 reload_file(File)

Reload file into the proper module.

bug

- If modules import each other, we must load them in the proper order for import/export dependencies.

  120:- public reload_file/1.                % Used by PDT
  121
  122reload_file(File) :-
  123    source_base_name(File, Compile),
  124    findall(M-Opts,
  125            source_file_property(File, load_context(M, _, Opts)),
  126            Modules),
  127    (   Modules = [First-OptsFirst|Rest]
  128    ->  Extra = [ silent(false),
  129                  register(false)
  130                ],
  131        merge_options([if(true)|Extra], OptsFirst, OFirst),
  132        debug(make, 'Make: First load ~q', [load_files(First:Compile, OFirst)]),
  133        load_files(First:Compile, OFirst),
  134        forall(member(Context-Opts, Rest),
  135               ( merge_options([if(not_loaded)|Extra], Opts, O),
  136                 debug(make, 'Make: re-import: ~q',
  137                       [load_files(Context:Compile, O)]),
  138                 load_files(Context:Compile, O)
  139               ))
  140    ;   load_files(user:Compile)
  141    ).
  142
  143source_base_name(File, Compile) :-
  144    file_name_extension(Compile, Ext, File),
  145    user:prolog_file_type(Ext, prolog),
  146    !.
  147source_base_name(File, File).

 prolog:make_hook(+When, +Files) is semidet

This hook is called by make/0. It is called with the following values for When:

before

The hook is called before reloading starts. The default action is to do nothing.

after

The hook is called after reloading completed. The default action is to call list_undefined/1 as:

list_undefined([scan(local)]).

The hook can be used to change program validation, stop or restart services, etc.

Arguments:

Files

- is a list holding the canonical file names of the files that need to be reloaded. This list can be empty.