View source with raw comments or as raw
    1/*  Part of SWI-Prolog
    2
    3    Author:        Jan Wielemaker
    4    E-mail:        J.Wielemaker@vu.nl
    5    WWW:           http://www.swi-prolog.org
    6    Copyright (c)  2006-2015, University of Amsterdam
    7                              VU University Amsterdam
    8    All rights reserved.
    9
   10    Redistribution and use in source and binary forms, with or without
   11    modification, are permitted provided that the following conditions
   12    are met:
   13
   14    1. Redistributions of source code must retain the above copyright
   15       notice, this list of conditions and the following disclaimer.
   16
   17    2. Redistributions in binary form must reproduce the above copyright
   18       notice, this list of conditions and the following disclaimer in
   19       the documentation and/or other materials provided with the
   20       distribution.
   21
   22    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
   23    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
   24    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
   25    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
   26    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
   27    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
   28    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
   29    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
   30    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   31    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
   32    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
   33    POSSIBILITY OF SUCH DAMAGE.
   34*/
   35
   36:- module(pairs,
   37          [ pairs_keys_values/3,
   38            pairs_values/2,
   39            pairs_keys/2,
   40            group_pairs_by_key/2,
   41            transpose_pairs/2,
   42            map_list_to_pairs/3
   43          ]).

Operations on key-value lists

This module implements common operations on Key-Value lists, also known as Pairs. Pairs have great practical value, especially due to keysort/2 and the library assoc.pl.

This library is based on disussion in the SWI-Prolog mailinglist, including specifications from Quintus and a library proposal by Richard O'Keefe.

author
- Jan Wielemaker */
See also
- keysort/2, library(assoc)
 pairs_keys_values(?Pairs, ?Keys, ?Values) is det
True if Keys holds the keys of Pairs and Values the values.

Deterministic if any argument is instantiated to a finite list and the others are either free or finite lists. All three lists are in the same order.

See also
- pairs_values/2 and pairs_keys/2.
   69pairs_keys_values(Pairs, Keys, Values) :-
   70    (   nonvar(Pairs) ->
   71        pairs_keys_values_(Pairs, Keys, Values)
   72    ;   nonvar(Keys) ->
   73        keys_values_pairs(Keys, Values, Pairs)
   74    ;   values_keys_pairs(Values, Keys, Pairs)
   75    ).
   76
   77pairs_keys_values_([], [], []).
   78pairs_keys_values_([K-V|Pairs], [K|Keys], [V|Values]) :-
   79    pairs_keys_values_(Pairs, Keys, Values).
   80
   81keys_values_pairs([], [], []).
   82keys_values_pairs([K|Ks], [V|Vs], [K-V|Pairs]) :-
   83    keys_values_pairs(Ks, Vs, Pairs).
   84
   85values_keys_pairs([], [], []).
   86values_keys_pairs([V|Vs], [K|Ks], [K-V|Pairs]) :-
   87    values_keys_pairs(Vs, Ks, Pairs).
 pairs_values(+Pairs, -Values) is det
Remove the keys from a list of Key-Value pairs. Same as pairs_keys_values(Pairs, _, Values)
   94pairs_values([], []).
   95pairs_values([_-V|T0], [V|T]) :-
   96    pairs_values(T0, T).
 pairs_keys(+Pairs, -Keys) is det
Remove the values from a list of Key-Value pairs. Same as pairs_keys_values(Pairs, Keys, _)
  104pairs_keys([], []).
  105pairs_keys([K-_|T0], [K|T]) :-
  106    pairs_keys(T0, T).
 group_pairs_by_key(+Pairs, -Joined:list(Key-Values)) is det
Group values with equivalent (==/2) consecutive keys. For example:
?- group_pairs_by_key([a-2, a-1, b-4, a-3], X).

X = [a-[2,1], b-[4], a-[3]]

Sorting the list of pairs before grouping can be used to group all values associated with a key. For example, finding all values associated with the largest key:

?- sort(1, @>=, [a-1, b-2, c-3, a-4, a-5, c-6], Ps),
   group_pairs_by_key(Ps, [K-Vs|_]).
K = c,
Vs = [3, 6].

In this example, sorting by key only (first argument of sort/4 is 1) ensures that the order of the values in the original list of pairs is maintained.

Arguments:
Pairs- Key-Value list
Joined- List of Key-Group, where Group is the list of Values associated with equivalent consecutive Keys in the same order as they appear in Pairs.
  141group_pairs_by_key([], []).
  142group_pairs_by_key([M-N|T0], [M-[N|TN]|T]) :-
  143    same_key(M, T0, TN, T1),
  144    group_pairs_by_key(T1, T).
  145
  146same_key(M0, [M-N|T0], [N|TN], T) :-
  147    M0 == M,
  148    !,
  149    same_key(M, T0, TN, T).
  150same_key(_, L, [], L).
 transpose_pairs(+Pairs, -Transposed) is det
Swap Key-Value to Value-Key. The resulting list is sorted using keysort/2 on the new key.
  158transpose_pairs(Pairs, Transposed) :-
  159    flip_pairs(Pairs, Flipped),
  160    keysort(Flipped, Transposed).
  161
  162flip_pairs([], []).
  163flip_pairs([Key-Val|Pairs], [Val-Key|Flipped]) :-
  164    flip_pairs(Pairs, Flipped).
 map_list_to_pairs(:Function, +List, -Keyed)
Create a Key-Value list by mapping each element of List. For example, if we have a list of lists we can create a list of Length-List using
        map_list_to_pairs(length, ListOfLists, Pairs),
  177:- meta_predicate
  178    map_list_to_pairs(2, +, -).  179
  180map_list_to_pairs(Function, List, Pairs) :-
  181    map_list_to_pairs2(List, Function, Pairs).
  182
  183map_list_to_pairs2([], _, []).
  184map_list_to_pairs2([H|T0], Pred, [K-H|T]) :-
  185    call(Pred, H, K),
  186    map_list_to_pairs2(T0, Pred, T)