1/* Part of SWI-Prolog 2 3 Author: Markus Triska and Matt Lilley 4 WWW: http://www.swi-prolog.org 5 Copyright (c) 2004-2017, SWI-Prolog Foundation 6 VU University Amsterdam 7 All rights reserved. 8 9 Redistribution and use in source and binary forms, with or without 10 modification, are permitted provided that the following conditions 11 are met: 12 13 1. Redistributions of source code must retain the above copyright 14 notice, this list of conditions and the following disclaimer. 15 16 2. Redistributions in binary form must reproduce the above copyright 17 notice, this list of conditions and the following disclaimer in 18 the documentation and/or other materials provided with the 19 distribution. 20 21 THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS 22 "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT 23 LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS 24 FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE 25 COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, 26 INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, 27 BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; 28 LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER 29 CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT 30 LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN 31 ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE 32 POSSIBILITY OF SUCH DAMAGE. 33*/ 34 35:- module(crypto, 36 [ crypto_n_random_bytes/2, % +N, -Bytes 37 crypto_data_hash/3, % +Data, -Hash, +Options 38 crypto_file_hash/3, % +File, -Hash, +Options 39 crypto_context_new/2, % -Context, +Options 40 crypto_data_context/3, % +Data, +C0, -C 41 crypto_context_hash/2, % +Context, -Hash 42 crypto_open_hash_stream/3, % +InStream, -HashStream, +Options 43 crypto_stream_hash/2, % +HashStream, -Hash 44 crypto_password_hash/2, % +Password, ?Hash 45 crypto_password_hash/3, % +Password, ?Hash, +Options 46 crypto_data_hkdf/4, % +Data, +Length, -Bytes, +Options 47 ecdsa_sign/4, % +Key, +Data, -Signature, +Options 48 ecdsa_verify/4, % +Key, +Data, +Signature, +Options 49 crypto_data_decrypt/6, % +CipherText, +Algorithm, +Key, +IV, -PlainText, +Options 50 crypto_data_encrypt/6, % +PlainText, +Algorithm, +Key, +IV, -CipherText, +Options 51 hex_bytes/2, % ?Hex, ?List 52 rsa_private_decrypt/4, % +Key, +Ciphertext, -Plaintext, +Enc 53 rsa_private_encrypt/4, % +Key, +Plaintext, -Ciphertext, +Enc 54 rsa_public_decrypt/4, % +Key, +Ciphertext, -Plaintext, +Enc 55 rsa_public_encrypt/4, % +Key, +Plaintext, -Ciphertext, +Enc 56 rsa_sign/4, % +Key, +Data, -Signature, +Options 57 rsa_verify/4, % +Key, +Data, +Signature, +Options 58 crypto_modular_inverse/3, % +X, +M, -Y 59 crypto_generate_prime/3, % +N, -P, +Options 60 crypto_is_prime/2, % +P, +Options 61 crypto_name_curve/2, % +Name, -Curve 62 crypto_curve_order/2, % +Curve, -Order 63 crypto_curve_generator/2, % +Curve, -Generator 64 crypto_curve_scalar_mult/4 % +Curve, +Scalar, +Point, -Result 65 ]). 66:- use_module(library(option)). 67 68:- use_foreign_library(foreign(crypto4pl)).
One way to relate such a list of bytes to an integer is to use CLP(FD) constraints as follows:
:- use_module(library(clpfd)).
bytes_integer(Bs, N) :-
foldl(pow, Bs, 0-0, N-_).
pow(B, N0-I0, N-I) :-
B in 0..255,
N #= N0 + B*256^I0,
I #= I0 + 1.
With this definition, you can generate a random 256-bit integer from a list of 32 random bytes:
?- crypto_n_random_bytes(32, Bs), bytes_integer(Bs, I). Bs = [98, 9, 35, 100, 126, 174, 48, 176, 246|...], I = 109798276762338328820827...(53 digits omitted).
The above relation also works in the other direction, letting you translate an integer to a list of bytes. In addition, you can use hex_bytes/2 to convert bytes to tokens that can be easily exchanged in your applications. This also works if you have compiled SWI-Prolog without support for large integers.
132/* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 133 SHA256 is the current default for several hash-related predicates. 134 It is deemed sufficiently secure for the foreseeable future. Yet, 135 application programmers must be aware that the default may change in 136 future versions. The hash predicates all yield the algorithm they 137 used if a Prolog variable is used for the pertaining option. 138- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - */ 139 140default_hash(sha256). 141 142functor_hash_options(F, Hash, Options0, [Option|Options]) :- 143 Option =.. [F,Hash], 144 ( select(Option, Options0, Options) -> 145 ( var(Hash) -> 146 default_hash(Hash) 147 ; must_be(atom, Hash) 148 ) 149 ; Options = Options0, 150 default_hash(Hash) 151 ).
md5 (insecure), sha1 (insecure), ripemd160,
sha224, sha256, sha384, sha512, sha3_224, sha3_256,
sha3_384, sha3_512, blake2s256 or blake2b512. The BLAKE
digest algorithms require OpenSSL 1.1.0 or greater, and the SHA-3
algorithms require OpenSSL 1.1.1 or greater. The default is a
cryptographically secure algorithm. If you specify a variable,
then that variable is unified with the algorithm that was used.utf8. The
other meaningful value is octet, claiming that Data contains
raw bytes.
188crypto_data_hash(Data, Hash, Options) :-
189 crypto_context_new(Context0, Options),
190 crypto_data_context(Data, Context0, Context),
191 crypto_context_hash(Context, Hash).198crypto_file_hash(File, Hash, Options) :- 199 setup_call_cleanup(open(File, read, In, [type(binary)]), 200 crypto_stream_hash(In, Hash, Options), 201 close(In)). 202 203crypto_stream_hash(Stream, Hash, Options) :- 204 crypto_context_new(Context0, Options), 205 update_hash(Stream, Context0, Context), 206 crypto_context_hash(Context, Hash). 207 208update_hash(In, Context0, Context) :- 209 ( at_end_of_stream(In) 210 -> Context = Context0 211 ; read_pending_codes(In, Data, []), 212 crypto_data_context(Data, Context0, Context1), 213 update_hash(In, Context1, Context) 214 ).
226crypto_context_new(Context, Options0) :-
227 functor_hash_options(algorithm, _, Options0, Options),
228 '_crypto_context_new'(Context, Options).This predicate allows a hash to be computed in chunks, which may be important while working with Metalink (RFC 5854), BitTorrent or similar technologies, or simply with big files.
242crypto_data_context(Data, Context0, Context) :-
243 '_crypto_hash_context_copy'(Context0, Context),
244 '_crypto_update_hash_context'(Data, Context).
253crypto_context_hash(Context, Hash) :-
254 '_crypto_hash_context_copy'(Context, Copy),
255 '_crypto_hash_context_hash'(Copy, List),
256 hex_bytes(Hash, List).true (default), closing the filter stream also closes the
original (parent) stream.
268crypto_open_hash_stream(OrgStream, HashStream, Options) :-
269 crypto_context_new(Context, Options),
270 '_crypto_open_hash_stream'(OrgStream, HashStream, Context).282crypto_stream_hash(Stream, Hash) :- 283 '_crypto_stream_hash_context'(Stream, Context), 284 crypto_context_hash(Context, Hash). 285 286/* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 287 The so-called modular crypt format (MCF) is a standard for encoding 288 password hash strings. However, there's no official specification 289 document describing it. Nor is there a central registry of 290 identifiers or rules. This page describes what is known about it: 291 292 https://pythonhosted.org/passlib/modular_crypt_format.html 293 294 As of 2016, the MCF is deprecated in favor of the PHC String Format: 295 296 https://github.com/P-H-C/phc-string-format/blob/master/phc-sf-spec.md 297 298 This is what we are using below. For the time being, it is best to 299 treat these hashes as opaque atoms in applications. Please let me 300 know if you need to rely on any specifics of this format. 301- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - */
crypto_password_hash(Password, Hash, []) and computes a
password-based hash using the default options.
310crypto_password_hash(Password, Hash) :-
311 ( nonvar(Hash) ->
312 must_be(atom, Hash),
313 split_string(Hash, "$", "$", ["pbkdf2-sha512",Ps,SaltB64,HashB64]),
314 atom_to_term(Ps, t=Iterations, []),
315 bytes_base64(SaltBytes, SaltB64),
316 bytes_base64(HashBytes, HashB64),
317 '_crypto_password_hash'(Password, SaltBytes, Iterations, HashBytes)
318 ; crypto_password_hash(Password, Hash, [])
319 ).Another important distinction is that equal passwords must yield, with very high probability, different hashes. For this reason, cryptographically strong random numbers are automatically added to the password before a hash is derived.
Hash is unified with an atom that contains the computed hash and all parameters that were used, except for the password. Instead of storing passwords, store these hashes. Later, you can verify the validity of a password with crypto_password_hash/2, comparing the then entered password to the stored hash. If you need to export this atom, you should treat it as opaque ASCII data with up to 255 bytes of length. The maximal length may increase in the future.
Admissible options are:
pbkdf2-sha512, which is therefore also the default.Currently, PBKDF2 with SHA-512 is used as the hash derivation function, using 128 bits of salt. All default parameters, including the algorithm, are subject to change, and other algorithms will also become available in the future. Since computed hashes store all parameters that were used during their derivation, such changes will not affect the operation of existing deployments. Note though that new hashes will then be computed with the new default parameters.
372crypto_password_hash(Password, Hash, Options) :- 373 must_be(list, Options), 374 option(cost(C), Options, 17), 375 Iterations is 2^C, 376 Algorithm = 'pbkdf2-sha512', % current default and only option 377 option(algorithm(Algorithm), Options, Algorithm), 378 ( option(salt(SaltBytes), Options) -> 379 true 380 ; crypto_n_random_bytes(16, SaltBytes) 381 ), 382 '_crypto_password_hash'(Password, SaltBytes, Iterations, HashBytes), 383 bytes_base64(HashBytes, HashB64), 384 bytes_base64(SaltBytes, SaltB64), 385 format(atom(Hash), 386 "$pbkdf2-sha512$t=~d$~w$~w", [Iterations,SaltB64,HashB64]). 387 388 389/* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 390 Bidirectional Bytes <-> Base64 conversion as required by PHC format. 391 392 Note that *no padding* must be used, and that we must be able 393 to encode the whole range of bytes, not only UTF-8 sequences! 394- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - */ 395 396bytes_base64(Bytes, Base64) :- 397 ( var(Bytes) -> 398 base64_encoded(Atom, Base64, [padding(false)]), 399 atom_codes(Atom, Bytes) 400 ; atom_codes(Atom, Bytes), 401 base64_encoded(Atom, Base64, [padding(false)]) 402 ).
Admissible options are:
utf8 (default) or octet, denoting
the representation of Data as in crypto_data_hash/3.
The info/1 option can be used to generate multiple keys from a
single master key, using for example values such as key and
iv, or the name of a file that is to be encrypted.
This predicate requires OpenSSL 1.1.0 or greater.
439crypto_data_hkdf(Data, L, Bytes, Options0) :-
440 functor_hash_options(algorithm, Algorithm, Options0, Options),
441 option(salt(SaltBytes), Options, []),
442 option(info(Info), Options, ''),
443 option(encoding(Enc), Options, utf8),
444 '_crypto_data_hkdf'(Data, SaltBytes, Info, Algorithm, Enc, L, Bytes).hex) assumes that Data is
an atom, string, character list or code list representing the
data in hexadecimal notation. See rsa_sign/4 for an example.
Options:
hex. Alternatives
are octet, utf8 and text.461ecdsa_sign(private_key(ec(Private,Public0,Curve)), Data0, Signature, Options) :- 462 option(encoding(Enc0), Options, hex), 463 hex_encoding(Enc0, Data0, Enc, Data), 464 hex_bytes(Public0, Public), 465 '_crypto_ecdsa_sign'(ec(Private,Public,Curve), Data, Enc, Signature). 466 467hex_encoding(hex, Data0, octet, Data) :- !, 468 hex_bytes(Data0, Data). 469hex_encoding(Enc, Data, Enc, Data).
Options:
hex. Alternatives
are octet, utf8 and text.
482ecdsa_verify(public_key(ec(Private,Public0,Curve)), Data0, Signature0, Options) :-
483 option(encoding(Enc0), Options, hex),
484 hex_encoding(Enc0, Data0, Enc, Data),
485 hex_bytes(Public0, Public),
486 hex_bytes(Signature0, Signature),
487 '_crypto_ecdsa_verify'(ec(Private,Public,Curve), Data, Enc, Signature).Example:
?- hex_bytes('501ACE', Bs).
Bs = [80, 26, 206].
511hex_bytes(Hs, Bytes) :- 512 ( ground(Hs) -> 513 string_chars(Hs, Chars), 514 ( phrase(hex_bytes(Chars), Bytes) 515 -> true 516 ; domain_error(hex_encoding, Hs) 517 ) 518 ; must_be(list(between(0,255)), Bytes), 519 phrase(bytes_hex(Bytes), Chars), 520 atom_chars(Hs, Chars) 521 ). 522 523hex_bytes([]) --> []. 524hex_bytes([H1,H2|Hs]) --> [Byte], 525 { char_type(H1, xdigit(High)), 526 char_type(H2, xdigit(Low)), 527 Byte is High*16 + Low }, 528 hex_bytes(Hs). 529 530bytes_hex([]) --> []. 531bytes_hex([B|Bs]) --> 532 { High is B>>4, 533 Low is B /\ 0xf, 534 char_type(C0, xdigit(High)), 535 char_type(C1, xdigit(Low)) 536 }, 537 [C0,C1], 538 bytes_hex(Bs).
Options:
utf8. Alternatives
are utf8 and octet.pkcs1. Alternatives
are pkcs1_oaep, sslv23 and none. Note that none should
only be used if you implement cryptographically sound padding
modes in your application code as encrypting unpadded data with
RSA is insecuresha1, sha224, sha256, sha384 or sha512. The
default is a cryptographically secure algorithm. If you
specify a variable, then it is unified with the algorithm that
was used.hex. Alternatives
are octet, utf8 and text.
This predicate can be used to compute a sha256WithRSAEncryption
signature as follows:
sha256_with_rsa(PemKeyFile, Password, Data, Signature) :-
Algorithm = sha256,
read_key(PemKeyFile, Password, Key),
crypto_data_hash(Data, Hash, [algorithm(Algorithm),
encoding(octet)]),
rsa_sign(Key, Hash, Signature, [type(Algorithm)]).
read_key(File, Password, Key) :-
setup_call_cleanup(
open(File, read, In, [type(binary)]),
load_private_key(In, Password, Key),
close(In)).
Note that a hash that is computed by crypto_data_hash/3 can be directly used in rsa_sign/4 as well as ecdsa_sign/4.
606rsa_sign(Key, Data0, Signature, Options0) :-
607 functor_hash_options(type, Type, Options0, Options),
608 option(encoding(Enc0), Options, hex),
609 hex_encoding(Enc0, Data0, Enc, Data),
610 rsa_sign(Key, Type, Enc, Data, Signature).Options:
sha1,
sha224, sha256, sha384 or sha512. The default is the
same as for rsa_sign/4. This option must match the algorithm
that was used for signing. When operating with different parties,
the used algorithm must be communicated over an authenticated
channel.hex. Alternatives
are octet, utf8 and text.
631rsa_verify(Key, Data0, Signature0, Options0) :-
632 functor_hash_options(type, Type, Options0, Options),
633 option(encoding(Enc0), Options, hex),
634 hex_encoding(Enc0, Data0, Enc, Data),
635 hex_bytes(Signature0, Signature),
636 rsa_verify(Key, Type, Enc, Data, Signature).utf8.
Alternatives are utf8 and octet.block. You can disable padding by supplying none here.672crypto_data_decrypt(CipherText, Algorithm, Key, IV, PlainText, Options) :- 673 ( option(tag(Tag), Options) -> 674 option(min_tag_length(MinTagLength), Options, 16), 675 length(Tag, TagLength), 676 compare(C, TagLength, MinTagLength), 677 tag_length_ok(C, Tag) 678 ; Tag = [] 679 ), 680 '_crypto_data_decrypt'(CipherText, Algorithm, Key, IV, 681 Tag, PlainText, Options). 682 683% This test is important to prevent truncation attacks of the tag. 684 685tag_length_ok(=, _). 686tag_length_ok(>, _). 687tag_length_ok(<, Tag) :- domain_error(tag_is_too_short, Tag).
PlainText must be a string, atom or list of codes or characters, and CipherText is created as a string. Key and IV are typically lists of bytes, though atoms and strings are also permitted. Algorithm must be an algorithm which your copy of OpenSSL knows about.
Keys and IVs can be chosen at random (using for example crypto_n_random_bytes/2) or derived from input keying material (IKM) using for example crypto_data_hkdf/4. This input is often a shared secret, such as a negotiated point on an elliptic curve, or the hash that was computed from a password via crypto_password_hash/3 with a freshly generated and specified salt.
Reusing the same combination of Key and IV typically leaks at least
some information about the plaintext. For example, identical
plaintexts will then correspond to identical ciphertexts. For some
algorithms, reusing an IV with the same Key has disastrous results
and can cause the loss of all properties that are otherwise
guaranteed. Especially in such cases, an IV is also called a
nonce (number used once). If an IV is not needed for your
algorithm (such as 'aes-128-ecb') then any value can be provided
as it will be ignored by the underlying implementation. Note that
such algorithms do not provide semantic security and are thus
insecure. You should use stronger algorithms instead.
It is safe to store and transfer the used initialization vector (or nonce) in plain text, but the key must be kept secret.
Commonly used algorithms include:
'chacha20-poly1305''aes-128-gcm''aes-128-cbc'Options:
utf8. Alternatives
are utf8 and octet.block. You can disable padding by supplying none here. If
padding is disabled for block ciphers, then the length of the
ciphertext must be a multiple of the block size.For example, with OpenSSL 1.1.0 and greater, we can use the ChaCha20 stream cipher with the Poly1305 authenticator. This cipher uses a 256-bit key and a 96-bit nonce, i.e., 32 and 12 bytes, respectively:
?- Algorithm = 'chacha20-poly1305',
crypto_n_random_bytes(32, Key),
crypto_n_random_bytes(12, IV),
crypto_data_encrypt("this is some input", Algorithm,
Key, IV, CipherText, [tag(Tag)]),
crypto_data_decrypt(CipherText, Algorithm,
Key, IV, RecoveredText, [tag(Tag)]).
Algorithm = 'chacha20-poly1305',
Key = [65, 147, 140, 197, 27, 60, 198, 50, 218|...],
IV = [253, 232, 174, 84, 168, 208, 218, 168, 228|...],
CipherText = <binary string>,
Tag = [248, 220, 46, 62, 255, 9, 178, 130, 250|...],
RecoveredText = "this is some input".
In this example, we use crypto_n_random_bytes/2 to generate a key and nonce from cryptographically secure random numbers. For repeated applications, you must ensure that a nonce is only used once together with the same key. Note that for authenticated encryption schemes, the tag that was computed during encryption is necessary for decryption. It is safe to store and transfer the tag in plain text.
809crypto_data_encrypt(PlainText, Algorithm, Key, IV, CipherText, Options) :-
810 ( option(tag(AuthTag), Options) ->
811 option(tag_length(AuthLength), Options, 16)
812 ; AuthTag = _,
813 AuthLength = -1
814 ),
815 '_crypto_data_encrypt'(PlainText, Algorithm, Key, IV,
816 AuthLength, AuthTag, CipherText, Options).825crypto_modular_inverse(X, M, Y) :- 826 integer_serialized(X, XS), 827 integer_serialized(M, MS), 828 '_crypto_modular_inverse'(XS, MS, YHex), 829 hex_to_integer(YHex, Y). 830 831integer_serialized(I, serialized(S)) :- 832 must_be(integer, I), 833 integer_atomic_sign(I, Sign), 834 Abs is abs(I), 835 format(atom(A0), "~16r", [Abs]), 836 atom_length(A0, L), 837 Rem is L mod 2, 838 hex_pad(Rem, Sign, A0, S). 839 840integer_atomic_sign(I, S) :- 841 Sign is sign(I), 842 sign_atom(Sign, S). 843 844sign_atom(-1, '-'). 845sign_atom( 0, ''). 846sign_atom( 1, ''). 847 848hex_pad(0, Sign, A0, A) :- atom_concat(Sign, A0, A). 849hex_pad(1, Sign, A0, A) :- atomic_list_concat([Sign,'0',A0], A). 850 851pow256(Byte, N0-I0, N-I) :- 852 N is N0 + Byte*256^I0, 853 I is I0 + 1. 854 855hex_to_integer(Hex, N) :- 856 hex_bytes(Hex, Bytes0), 857 reverse(Bytes0, Bytes), 858 foldl(pow256, Bytes, 0-0, N-_).
true (default is false), then a safe prime
is generated. This means that P is of the form 2*Q + 1 where Q
is also prime.
870crypto_generate_prime(Bits, P, Options) :-
871 must_be(list, Options),
872 option(safe(Safe), Options, false),
873 '_crypto_generate_prime'(Bits, Hex, Safe, Options),
874 hex_to_integer(Hex, P).
886crypto_is_prime(P0, Options) :-
887 must_be(integer, P0),
888 must_be(list, Options),
889 option(iterations(N), Options, -1),
890 integer_serialized(P0, P),
891 '_crypto_is_prime'(P, N).prime256v1 and
secp256k1.
If you have OpenSSL installed, you can get a list of supported curves via:
$ openssl ecparam -list_curves
914crypto_curve_order(Curve, Order) :-
915 '_crypto_curve_order'(Curve, Hex),
916 hex_to_integer(Hex, Order).
923crypto_curve_generator(Curve, point(X,Y)) :-
924 '_crypto_curve_generator'(Curve, X0, Y0),
925 hex_to_integer(X0, X),
926 hex_to_integer(Y0, Y).933crypto_curve_scalar_mult(Curve, S0, point(X0,Y0), point(A,B)) :- 934 maplist(integer_serialized, [S0,X0,Y0], [S,X,Y]), 935 '_crypto_curve_scalar_mult'(Curve, S, X, Y, A0, B0), 936 hex_to_integer(A0, A), 937 hex_to_integer(B0, B). 938 939 940 /******************************* 941 * Sandboxing * 942 *******************************/ 943 944:- multifile sandbox:safe_primitive/1. 945 946sandbox:safe_primitive(crypto:hex_bytes(_,_)). 947sandbox:safe_primitive(crypto:crypto_n_random_bytes(_,_)). 948 949sandbox:safe_primitive(crypto:crypto_data_hash(_,_,_)). 950sandbox:safe_primitive(crypto:crypto_data_context(_,_,_)). 951sandbox:safe_primitive(crypto:crypto_context_new(_,_)). 952sandbox:safe_primitive(crypto:crypto_context_hash(_,_)). 953 954sandbox:safe_primitive(crypto:crypto_password_hash(_,_)). 955sandbox:safe_primitive(crypto:crypto_password_hash(_,_,_)). 956sandbox:safe_primitive(crypto:crypto_data_hkdf(_,_,_,_)). 957 958sandbox:safe_primitive(crypto:ecdsa_sign(_,_,_,_)). 959sandbox:safe_primitive(crypto:ecdsa_verify(_,_,_,_)). 960 961sandbox:safe_primitive(crypto:rsa_sign(_,_,_,_)). 962sandbox:safe_primitive(crypto:rsa_verify(_,_,_,_)). 963sandbox:safe_primitive(crypto:rsa_public_encrypt(_,_,_,_)). 964sandbox:safe_primitive(crypto:rsa_public_decrypt(_,_,_,_)). 965sandbox:safe_primitive(crypto:rsa_private_encrypt(_,_,_,_)). 966sandbox:safe_primitive(crypto:rsa_private_decrypt(_,_,_,_)). 967 968sandbox:safe_primitive(crypto:crypto_data_decrypt(_,_,_,_,_,_)). 969sandbox:safe_primitive(crypto:crypto_data_encrypt(_,_,_,_,_,_)). 970 971sandbox:safe_primitive(crypto:crypto_modular_inverse(_,_,_)). 972sandbox:safe_primitive(crypto:crypto_generate_prime(_,_,_)). 973sandbox:safe_primitive(crypto:crypto_is_prime(_,_)). 974 975sandbox:safe_primitive(crypto:crypto_name_curve(_,_)). 976sandbox:safe_primitive(crypto:crypto_curve_order(_,_)). 977sandbox:safe_primitive(crypto:crypto_curve_generator(_,_)). 978sandbox:safe_primitive(crypto:crypto_curve_scalar_mult(_,_,_,_)). 979 980 /******************************* 981 * MESSAGES * 982 *******************************/ 983 984:- multifile 985 prolog:error_message//1. 986 987prologerror_message(ssl_error(ID, _Library, Function, Reason)) --> 988 [ 'SSL(~w) ~w: ~w'-[ID, Function, Reason] ]
Cryptography and authentication library
This library provides bindings to functionality of OpenSSL that is related to cryptography and authentication, not necessarily involving connections, sockets or streams.
The hash functionality of this library subsumes and extends that of
library(sha),library(hash_stream)andlibrary(md5)by providing a unified interface to all available digest algorithms.The underlying OpenSSL library (
libcrypto) is dynamically loaded if eitherlibrary(crypto)orlibrary(ssl)are loaded. Therefore, if your application useslibrary(ssl), you can uselibrary(crypto)for hashing without increasing the memory footprint of your application. In other cases, the specialised hashing libraries are more lightweight but less general alternatives tolibrary(crypto).